If your favorite weather data feed does not return a moon phase, you can use a script to generate a number for it, based on the date.

< Demo.
Left: current date.
Right: type in a test date (month-day-year) then click the night sky thumbnail.

I found the original snippet at voidware.com, which I translated into actionscript for use in my flash weather module. The function returns a frame number, which matches the correct moon phase in a range of frames in a movieclip. The shade is a shape tween, so you don’t have to draw all 30 phases as separate frames. In the flash, I’ve also added a dark background that turns lighter as the moon waxes fuller, like a real night sky would.

Just a simple moon looks like this:

And here’s a more complex one:

The moon shade is the same simple shape tween as the image above, but with a blur filter applied, a brightness of -30%, and blend: multiply.

getMoonPhase function:

//return frame number for moon phase display
function getMoonPhase(yr:Number, m:Number, d:Number):int{
	//based on http://www.voidware.com/moon_phase.htm
	//calculates the moon phase (frames 1-30 )
	// 1: new moon; 16: full moon
    if (m < 3) {
        yr -= 1;
        m += 12;
    }
    //m += 1;
    var c:Number = 365.25*yr;
    var e:Number = 30.6*m;
	//jd is total days elapsed
	//divide by the moon cycle (29.53 days)
    var jd:Number = (c+e+d-694039.09)/29.53;
	//subtract integer to leave fractional part
    jd = jd - int(jd);
	//range fraction from 0-30 and round by adding 0.5
	var frame:int = Math.round(jd*30 + 0.5);
    return frame;
}
//test: september 23, 2002, not a full moon?
//trace("22 sept 02: _phase: "+getMoonPhase(2002, 9, 22)); //<-21 Sept full moon
//trace("17 juli 08: _phase: "+getMoonPhase(2008, 7, 17)); //<-full moon
//trace("9 feb 09: _phase: "+getMoonPhase(2009, 2, 9)); //<-full moon

This function needs separate numbers for year, month and day, which I supply it by getting the system date – but it would be better to get a date out of the actual feed, and parse that for use with the function. Here’s how I get the values and call the function:

//call the function
var ndate = new Date();
var yr = ndate.getFullYear();
var m = int(ndate.getMonth())+1;
var d = ndate.getDate();
trace("moonPhase: "+getMoonPhase(yr, m, d)+", month: "+m+", d: "+d);
var maanframe = getMoonPhase(yr, m, d);

//is it night? show a moon
if(night) {
    weericon.maan.gotoAndStop(maanframe); //sets moon phase
}

To make the moon even more realistic, you could use this technique of using shape tweens for a shade overlay with a photo of the moon, of course.